5 Replies Latest reply on Aug 17, 2015 8:47 AM by Toby Erkson

    We are upgrading our server and need complete guidance on how to back the data up.

    Jamie F

      I see the data backup link on here but we are looking for more descriptive instructions that go beyond how to create a back up file in tabcmd. We are looking for step by step install instructions, going from 8.3 to 9.0. Can anyone point me to a better resource than what is stated on the data backup link under upgrade prep checklist. Thanks!

        • 1. Re: We are upgrading our server and need complete guidance on how to back the data up.
          Shankar Narayanan SGS

          Hi Jamie,

           

          This link here shows pretty much how to upgrade with all steps. You can read here  Upgrading Tableau Server | Tableau Software

           

          Following this should make the upgrade smooth unless you face some glitch let us know in specific so that we can help.

           

          Regards

          Shankar

          • 2. Re: We are upgrading our server and need complete guidance on how to back the data up.
            Railey Abdullah

            Hi Jamie,

             

            You just need to backup the file from tabadmin  <tabadmin backup <filename> -d>

             

            To upgrade just uninstall the software and install it with new version. Make sure that you not delete the path that you use to install the earlier version.

             

            Make sure that you install the new version on the same path.

             

            Thank You

            Best Regards

            Railey

            • 4. Re: We are upgrading our server and need complete guidance on how to back the data up.
              Ken Patton

              Backups should be made from the tabadmin command.

               

              Through long experience, here is how I handle major software upgrades.

               

              - Schedule an outage window. This is not an operation worth trying to do on the fly.

              - from the /Tableau Server/x.y/bin directory in a DOS window , do

                   tabadmin stop

                   tabadmin cleanup

                   tabadmin backup <filenmame>

               

              This is my "safety backup".  I then copy it over to a network-mounted drive on a different machine, hoping that I will never need it.

               

              While the backup is being made, it's a swell time to also be downloading the new version of Tableau Server in a web browser , if you haven't already.

               

              Then, from Control Panel -> Uninstall Software Programs, select Tableau Server.

               

              Doing this will automatically generate an "uninstall.tsbak" backup file, which a subsequent installer will be looking for when you upgrade.

               

              When the uninstall is complete, then initiate the installation of the new Tableau Server image (which hopefully you have downloaded before or during a prior step.)  If you take care to install it in exactly the same parent directory as your previous version, then the Installer will locate the "uninstall.tsbak" file there and use it to restore your old content. If you have free disk space equal to or greater than the size of the uninstall.tsbak file, then it should restore normally as part of the upgrade.

               

              Now Comes Miller Time (tm) .

              • 5. Re: We are upgrading our server and need complete guidance on how to back the data up.
                Toby Erkson

                I agree with Ken.

                 

                Here's a batch script I run on our Servers every time, before I upgrade:

                @ECHO OFF
                REM QA
                REM  by Toby Erkson, May 2013
                REM  Adapted from http://kb.tableausoftware.com/articles/knowledgebase/server-maintenance
                REM  No inputs required.
                SET sPath=D:\Application\Tableau\backups
                SET sLogPath=D:\Application\Tableau\Tableau_Server\logs
                SET dDate=%DATE:/=%
                
                ECHO.
                ECHO ----- BEGIN %dDate:~-4%-%dDate:~4,2%-%dDate:~6,2% %TIME% ----- >> %sLogPath%\backup.log 2>&1
                ECHO Stopping Tableau Server...
                ECHO Stopping Tableau Server... >> %sLogPath%\backup.log 2>&1
                tabadmin stop >> %sLogPath%\backup.log 2>&1
                ECHO.
                ECHO Zipping the log files...
                ECHO Zipping the log files... >> %sLogPath%\backup.log 2>&1
                tabadmin ziplogs -l -n -p "%sPath%\Tableau_QA_logs-%dDate:~-4%%dDate:~4,2%%dDate:~6,2%.zip" >> %sLogPath%\backup.log 2>&1
                ECHO.
                ECHO Backing up Tableau Server...
                ECHO Backing up Tableau Server... >> %sLogPath%\backup.log 2>&1
                tabadmin backup %sPath%\backup_QA --date >> %sLogPath%\backup.log 2>&1
                SET /a EL=%ERRORLEVEL%
                
                IF %EL% EQU 0 GOTO Success
                
                :Failure
                    ECHO.
                    ECHO Backup failed.
                    ECHO Error number: %EL%
                    ECHO Backup failed. >> %sLogPath%\backup.log 2>&1
                    ECHO Error number: %EL% >> %sLogPath%\backup.log 2>&1
                    ECHO.
                GOTO End
                
                :Success
                    ECHO.
                    ECHO Backup succeeded.
                    ECHO Backup file saved to in directory %sPath%
                    ECHO File name is Tab_QA-%dDate:~-4%%dDate:~4,2%%dDate:~6,2%.tsbak
                    ECHO Backup succeeded. >> %sLogPath%\backup.log 2>&1
                    ECHO Backup file saved to in directory %sPath% >> %sLogPath%\backup.log 2>&1
                    ECHO File name is Tab_QA-%dDate:~-4%%dDate:~4,2%%dDate:~6,2%.tsbak >> %sLogPath%\backup.log 2>&1
                    ECHO.
                    ECHO Performing cleanup...
                    ECHO Performing cleanup... >> %sLogPath%\backup.log 2>&1
                    tabadmin cleanup >> %sLogPath%\backup.log 2>&1
                    ECHO.
                    ECHO Logs files backed-up and cleaned.  Re-starting Tableau Server, please wait...
                    ECHO Logs files backed-up and cleaned.  Re-starting Tableau Server, please wait... >> %sLogPath%\backup.log 2>&1
                    tabadmin start >> %sLogPath%\backup.log 2>&1
                
                REM 15Oct2014 - No longer doing this because we want to keep server log files as long as possible (currently 183 days) for admin reporting.
                REM    ECHO.
                REM    ECHO Performing cleanup...
                REM    ECHO Performing cleanup... >> %sLogPath%\backup.log 2>&1
                REM    tabadmin cleanup >> %sLogPath%\backup.log 2>&1
                
                    ECHO.
                REM ECHO Pausing execution for 90 seconds and ignore keystrokes to insure server is running before continuing script.
                    timeout /t 90 /nobreak
                    tabadmin.exe status | findstr /i RUNNING
                    if "%errorlevel%"=="0" GOTO End
                
                :Failed
                    ECHO.
                    ECHO Re-start and/or Cleanup failed!
                    ECHO Re-start and/or Cleanup failed! >> %sLogPath%\backup.log 2>&1
                    REM We want the returned error level NOT to be zero
                    SET /a EL=%ERRORLEVEL%
                    ECHO Error level is %EL% >> %sLogPath%\backup.log 2>&1
                
                :End
                
                ECHO Backup operation finished.
                ECHO ----- END ----- %TIME% >> %sLogPath%\backup.log 2>&1
                REM The /b will return our error level
                EXIT /b %EL%
                

                 

                 

                FYI: How the file structure looks per our corp. requirements: